build.gradle

apply plugin: 'com.android.application'

def computeVersionCode(int code) {
    return code * 1000000 + android.defaultConfig.versionCode
}

def computeVersionName(String name) {
    return android.defaultConfig.versionName + "-" + name
}

android {
    compileSdkVersion project.ext.compileSdkVersion
    buildToolsVersion project.ext.buildToolsVersion
    defaultConfig {
        applicationId "com.termoneplus.securebox"

        minSdkVersion project.ext.minSdkVersion
        targetSdkVersion project.ext.targetSdkVersion

        versionCode 224
        versionName '2.2.4'

        // TermOnePlus applicationId
        manifestPlaceholders = [ termApplicationId:"com.termoneplus"]
        buildConfigField("String", "TERM_APPLICATION_ID", "\"com.termoneplus\"")

        vectorDrawables.useSupportLibrary = true

        externalNativeBuild {
            cmake {
                arguments "-DAPPLICATION_ID:STRING=${applicationId}"
            }
        }
    }
    externalNativeBuild {
        cmake {
            path "src/CMakeLists.txt"
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    flavorDimensions "abi"
    productFlavors {
        /* removed in NDK r18
        arm {
            dimension "abi"
            ndk {
                abiFilters "armeabi"
            }
            versionCode computeVersionCode(1)
            versionName computeVersionName("arm")
        }*/
        arm7 {
            dimension "abi"
            /* in NDK r18 minimal available platform is API 16
            // Remark: in emulator native commands crash if build is for "armeabi-v7a"
            // but work fine with "armeabi". Version 16(JELLY_BEAN) is lowest that
            // work fine with "armeabi-v7a".
            minSdkVersion 16
            */
            ndk {
                abiFilters "armeabi-v7a"
            }
            versionCode computeVersionCode(2)
            versionName computeVersionName("arm7")
        }
        i686 {
            dimension "abi"
            ndk {
                abiFilters "x86"
            }
            versionCode computeVersionCode(3)
            versionName computeVersionName("i686")
        }
        /* removed in NDK r18
        mips {
            dimension "abi"
            ndk {
                abiFilters "mips"
            }
            versionCode computeVersionCode(4)
            versionName computeVersionName("mips")
        }*/
        arm8 {
            dimension "abi"
            ndk {
                abiFilters "arm64-v8a"
            }
            versionCode computeVersionCode(5)
            versionName computeVersionName("arm8")
        }
        x86_64 {
            dimension "abi"
            ndk {
                abiFilters "x86_64"
            }
            versionCode computeVersionCode(6)
            versionName computeVersionName("x86_64")
        }
        /* removed in NDK r18
        mips64 {
            dimension "abi"
            ndk {
                abiFilters "mips64"
            }
            versionCode computeVersionCode(7)
            versionName computeVersionName("mips64")
        }*/
    }
}

dependencies {
    implementation fileTree(include: ['*.jar'], dir: 'libs')
    implementation 'androidx.appcompat:appcompat:1.1.0'
    implementation 'androidx.cardview:cardview:1.0.0'
    implementation 'com.google.android.material:material:1.0.0'
}

task elfcleaner(type: Exec) {
    // only unix
    commandLine 'sh', '-c', 'find build/*/stripped* -name lib*.so -exec elf-cleaner {} \\;'
}

tasks.whenTaskAdded { task ->
    if (task.name.matches('strip.*DebugSymbols')) {
        task.finalizedBy elfcleaner
    }
}